RIA 开发感想（二）— Flash VS Ajax

import AndyClass.ArrayToXml;
import mx.events.EventDispatcher;
import org.okyere.util.XMD;
class AndyClass.FlashConnAsp extends MovieClip
{
 //该类用于接受Flash发送的Array变量
 //Array变量通过ArrayToXml类转换为要发送的XML；
 //如果调用成功，则返回my_xml的内容！！！！
 //属性域
 private var m_Url : String;
 private var m_Params : Array;
 private var m_Params_str : String = "";
 private var m_Result_errormsg : String;
 private var m_NodeName : String
 private var m_urlhead : String;
 private var m_xmd : org.okyere.util.XMD;
 //private var myListener : Object = new Object ();
 private var m_Result : String //具体的结果
 //属性域
 public var addEventListener : Function;
 public var removeEventListener : Function;
 private var dispatchEvent : Function;
 private static var _mixin1 = EventDispatcher.initialize (AndyClass.FlashConnAsp.prototype);
 public function FlashConnAsp ()
 {
  trace ("  FlashConnAsp 构造 " );
 }
 //Setter Getter
 public function set Url (txt : String) : Void
 {
  m_Url = txt;
 }
 public function get Url () : String
 {
  return m_Url;
 }
 public function set Params (a : Array) : Void
 {
  m_Params = a;
 }
 public function set Params_str (a : String) : Void
 {
  m_Params_str = a;
 }
 public function set ResultMsg (a : String) : Void
 {
  m_Result_errormsg = a;
 }
 public function set NodeName (a : String) : Void
 {
  m_NodeName = a;
 }
 //
 public function sendAndload ()
 {
  if (m_Url != null && m_Url != undefined&&m_urlhead != undefined)
  {
   f_sendAndload ();
  } else if (m_urlhead == undefined)
  {
   trace ("m_urlhead未定义")
   f_load_urlhead ();
  }
 }
 //
 private function f_load_urlhead ()
 {
  var owner : Object = this;
  m_xmd = new XMD ();
  m_xmd.load ("config.xml");
  var myListener = new Object ();
  myListener.onXMDLoad = function (evtObj : Object)
  {
   //trace ("获取config.xml的参数 urlhead 成功: " + evtObj.data.url);
   owner.m_urlhead = evtObj.data.url;
   owner.f_onDataLoadXml ()
   owner.m_xmd.removeEventListener ("onXMDLoad", myListener);
   owner.f_sendAndload ();
  };
  m_xmd.addEventListener ("onXMDLoad", myListener);
 }
 private function f_sendAndload ()
 {
  var eventObj01 : Object = {
   type : "m_onLoadVars", target : _parent
  };
  dispatchEvent (eventObj01);
  var owner : Object = this;
  if (m_Params != undefined&&m_Params != null)
  {
   trace ("m_Params != null")
   var m_ToXml = new ArrayToXml (m_Params);
   m_ToXml._NodeName = m_NodeName;
   //my_xml与ASP约定的变量
   var m_Send_lv = new LoadVars ();
   var m_Result_lv = new LoadVars ();
   m_Send_lv.my_xml = m_ToXml.ToXml ();
  } else if (m_Params_str != undefined&&m_Params_str != "")
  {
   trace("－－－－－－－－－－－－－发出字符串参数。")
   var m_Send_lv = new LoadVars ();
   var m_Result_lv = new LoadVars ();
   m_Send_lv.my_xml = m_Params_str;
  } else
  {
   trace ("客户端发出没有参数的连接请求。")
   var m_Send_lv = new LoadVars ();
   var m_Result_lv = new LoadVars ();
  }
  var my_date = new Date ()
  trace ("sendxml = "+m_Send_lv.my_xml);
  m_Send_lv.sendAndLoad (String (m_urlhead + m_Url + "&time=" + my_date.getTime ()) , m_Result_lv, "POST");
  m_Result_lv.onLoad = function (success)
  {
   //LoadVars的载入事件
   trace ("Loadvars load")
   if (success)
   {
    //trace ("m_Result=" + m_Result_lv.my_xml)
    if (m_Result_lv.my_xml == owner.m_Result_errormsg)
    {
     owner.m_Result = "error"
    } else
    {
     owner.m_Result = m_Result_lv.my_xml
    }
   } else
   {
    owner.m_Result = "link_out"
   }
   owner.f_call ()
  };
 }
 private function f_call ()
 {
  var eventObj02 : Object = {
   type : "m_onDataLoadVars", target : _parent
  };
  eventObj02.Result = m_Result;
  dispatchEvent (eventObj02);
 }
 private function f_onDataLoadXml ()
 {
  trace ("f_onDataLoadXml 发布主题")
  var eventObj03 : Object = {
   type : "m_onDataLoadXml", target : _parent
  };
  //eventObj03.Result = m_Result;
  dispatchEvent (eventObj03);
 }
}