闪吧 AIYI2003©版权所有，网络媒体转载请注明出处，谢绝传统媒体以任何形式的转载或引用！
在FLASH MX的时代，大家就希望能在自己的作品中放入自定义右键菜单，现在FLASH升级到了2004，终于可以放上自己的右键菜单秀一下了：P（这对于游戏编写者——尤其是RPG游戏编写者来说，手中无疑又多了把利剑）
在2004中，主要使用ContextMenu类与ContextMenuItem类来对右键菜单进行控制。ContextMenu对象可以附加到特定的按钮（使用Button类的menu属性来实现）、影片剪辑（使用MovieClip类的menu属性来实现）或文本字段（使用TextField类的menu属性来实现）上，也可以附加到整个影片级别。
Flash Player 共有三种类型的上下文菜单：即标准菜单（在Flash Player 中右击时出现）、编辑菜单（在可选择或可编辑的文本字段上右击时出现）和错误菜单（当SWF文件未能加载到Flash Player中时出现）。只有标准菜单和编辑菜单才能使用ContextMenu类进行修改。自定义菜单项始终出现在Flash Player上下文菜单的顶部，并位于所有可见内置菜单项之上；内置菜单项和自定义菜单项之间由一个分隔条加以分隔。一个上下文菜单包含的自定义菜单项不能超过 15 个。
好了，不多说了，首先我们先来看一下在Flash Player中默认的右击菜单：在主场景中只有一帧的情况下（图1）
[IMG]
在主场景中有多帧的情况下（图2）
我们可以看到，在多帧的时候，比单帧时多了[“播放”、“循环”]、[“后退”、“快进”、“返回”]这两组共5项子菜单项。
（以下教程均以后者——主场景内有多帧的源文件为例进行讲解）
在右键菜单中，我们可以看到七组共13项菜单项，除“设置...”与“关于...”无法隐藏外，其他菜单组均可用AS来实现隐藏。
★隐藏右击菜单
我们先在主场景的第一帧中加入如下AS代码：
//===自定义右击菜单===AIYI2003 (2004.01.03)
myMenu = new ContextMenu();
myMenu.hideBuiltInItems();
_root.menu = myMenu;
//***自定义右击菜单***代码结束
此AS代码段共五行，前面加“//”的代码为注解，并不执行。
第2行代码：myMenu = new ContextMenu()
用来创建新的 ContextMenu 对象。即创建自己的右键菜单——“myMenu”。
第3行代码：myMenu.hideBuiltInItems()
hideBuiltInItems()可以隐藏指定ContextMenu对象中的所有内置菜单项（“设置”与“关于”除外）。
加入这行代码，即把“放大”、“品质”、“播放”、“后退”、“打印”等菜单项全部隐藏。
第4行代码：_root.menu = myMenu
将主场景中的右键菜单设置成上面自定义的myMenu菜单。
输出为.swf文件测试（见图3）
我们可以看到，右击菜单中，除了不可以隐藏的“设置”与“关于”项之外，其它的菜单项都已被隐藏。
★只显示其中的其一项菜单（见图4）
比如只想在右击菜单中显示“品质”这个选项菜单，把“放大”、“播放”等菜单项去掉，我们可以在上面的AS语句中加入一行，变成：
//===自定义右键菜单===AIYI2003 (2004.01.03)
myMenu = new ContextMenu();
myMenu.hideBuiltInItems();
myMenu.builtInItems.quality = true
_root.menu = myMenu;
//***自定义右键菜单***代码结束
★只删除其中的某一项菜单（见图5）
比如只想去掉“缩放”菜单组，我们只要在第1帧中加入：
//===自定义右键菜单===AIYI2003 (2004.01.03)
myMenu = new ContextMenu();
myMenu.builtInItems.zoom = false
_root.menu = myMenu;
//***自定义右键菜单***代码结束
（图4实例）中我们加入了一行：myMenu.builtInItems.quality = true
（5）中我们用到了myMenu.builtInItems.zoom = false
这里我们来介绍一下builtInItems
builtInItems具有以下布尔型属性的对象：zoom、quality、play、loop、rewind、forward_back 和 print。（对应的中文菜单项为：缩放、品质、播放、循环、后退、快进与返回、打印）如果将这些变量设置为 false，则会删除指定 ContextMenu 对象中的相应菜单项。这些属性是可枚举的，并在默认情况下设置为 true。那么，朋友们可以举一反三，试着把（4）中myMenu.builtInItems.quality = true改成myMenu.builtInItems.play = true或是把（5）中的myMenu.builtInItems.zoom = false改成myMenu.builtInItems.forward_back = false，自己测试一下。
好了，看完上面写的，应该能显示与隐藏Flash Player系统自带的右键菜单项了吧，但是光能隐藏显示系统自带的菜单多没意思呀，如果我们想放上自己自制的右击菜单怎么办呢？答案——向下看：）
想在右击菜单中显示自己定义的内容，主要应用ContextMenuItem 类来完成。下面就详细介绍一下ContextMenuItem 类的使用。
★ContextMenuItem 类
使用 ContextMenuItem 类可创建在 Flash Player 上下文菜单中显示的自定义菜单项。
自定义菜单项将出现在右击菜单的顶部，并位于系统默认的菜单项之上。自定义菜单项与系统默认菜单项始终由分隔条隔开。向 Flash Player 中默认的菜单添加的自定义菜单项不得超过15个。每个菜单项必须至少包含一个可见字符，控制字符、换行符和其它空白字符将被忽略。所有菜单项的长度不得超过100个字符。如果菜单项与任何内置菜单项或其它自定义菜单项相同，则无论匹配菜单项是否可见，均会忽略该菜单项。对菜单项进行比较时将忽略大小写、标点和空格。
自定义菜单项中不能出现以下字词：Macromedia、Flash Player、或 设置。
☆测试自定义的右键菜单项
在FLASH MX 2004新建文档的第1帧中加入如下AS：
//===自定义右键菜单===AIYI2003 (2004.01.03)
myMenu = new ContextMenu();
myMenu.hideBuiltInItems();
myMenu.customItems.push(new ContextMenuItem("AIYI的右键菜单", test01));
function test01(obj, item) {
trace("test01");
}
_root.menu = myMenu;
//***自定义右键菜单***代码结束
我们Ctrl+回车测试（图6）
new ContextMenuItem("AIYI的右键菜单", test01)
是用来定义右击菜单中的文字（"AIYI的右键菜单"）与点击此菜单项时要执行的函数（test01）
添加新的菜单项时，要先创建一个新的ContextMenuItem对象，然后将其添加到
customItems数组。myMenu.customItems.push(new ContextMenuItem("AIYI的右键菜单", test01));
function test01(obj, item) {
trace("test01");
}
是用来定制test01函数，在function test01(obj, item){}内可以自己写入当此右键菜单项被按下时要执行的AS代码。
☆在自定义右键菜单中加入版权信息
在本人的[FLASH MX 2004系列教程]中swf格式的演示效果，右键菜单中有“版权信息”和友情链接等自定义菜单项，现在我就来说一下[版权信息]的制作步骤。
1、打开FLASH MX 2004新建一文档。
2、Ctrl+F8新建一MC（或在[插入]菜单中选[新建元件]），命名为“MC_版权”（图A_1）
3、点击“确定”进入“MC_版权”影片剪辑中编辑。
⑴把“图层1”改名为“背景”并用矩形工具画一圆角矩形
⑵新建一层，命名为“文字”，在此层输入版权信息。（图A_2）
⑶再次新建一层，命名为“隐形按钮”，将“背景”层的圆角矩形Copy一份，在此层原位粘贴。（图A_3）
⑷确保被原位粘贴的矩形是选中状态，按F8转换为按钮。命名为“隐形按钮”（图A_4）
⑸双击“隐形按钮”，进入其内部编辑。先选中第1帧，然后用鼠标将第1帧中的关键帧拖拽到第4帧（图A_5）
[IMG]/Upload/2004_Pack/2004132301079905.png[/IMG
⑹返回“MC_版权”影片剪辑中。选中“隐形按钮”按F9键打开AS动作面板，加入如下AS语句：
on (release) {
this._visible=0
}
4、返回主场景，把“图层1”重命名为“版权”，Ctrl+L打开库面板，将“MC_版权”拖入到主场景中来。并与主场景的中心对齐。在属性面板中将其的“实例名称”命名为：“copyright”。
5、新建一层，命名为“AS”在AS层的第1帧加入如下AS代码：
copyright._visible=0//隐藏版权信息
//===自定义右键菜单===AIYI2003 (2004.01.03)
myMenu = new ContextMenu();
myMenu.hideBuiltInItems();
myMenu.customItems.push(new ContextMenuItem("版权信息", CR));
function CR(obj, item) {
copyright._visible=1
}
_root.menu = myMenu;
//***自定义右键菜单***代码结束
6、Ctrl+回车测试。
在测试的时候我们单击鼠标右键，在弹出的右击菜单中选择“版权信息”，会‘弹出’一个版权信息的说明，当我们在那个版权说明上点击一下，版权信息就会消失。在右击菜单中加入版权说明，我们就可以用这种方式来实现，上面的方法比较简单，大家还可以加入自己的想像力，但出一个更漂亮的“版权信息”出来：）
但上面的方法，有一个不算问题的问题。为什么说是‘不算问题的问题’呢？我们可以看一下，当通过右击菜单打开版权信息的时候，不在‘弹出’的版权上点击鼠标（即不隐藏版权信息），再次单击鼠标右键，选择“版权信息”，会没有任何的反应——那是当然的了，因为版权信息的_visible的值为1，再次设为1，当然没反应了。这并不影响什么，但如果能去掉——很容易的去掉这样小小的“BUG”的话，当然还是要去掉了：P
实现这种效果，只要再加上两行AS语句即可：
在主场景“AS”层的第一帧中的function CR(obj, item) {}内加入：
myMenu.customItems[0].enabled = false
然后进入“MC_版权”影片剪辑中，在“隐形按钮”中on (release) {}内也加入一条语句：
_root.myMenu.customItems[0].enabled = true;
○这里简单介绍一下enabled属性；
enabled属性，是启用还是禁用指定菜单项的布尔值。当值为true时，启用指定菜单项，当值为false时，禁用指定的菜单项。默认情况下，此属性为 true。可以通过myMenu.customItems[0]来指定菜单项。myMenu.customItems[0]后面的[0]，就是你自定义的第一个菜单项，值为[1]时，就是自定义的第二个菜单项，依此类推。
FLASH源文件下载